Type [441b], CY of degree 16 -- lifting to a 3-fold with components of degrees 8, 8

We construct via linkage an arithmetically Gorenstein 3-fold $X = X_{8} \cup X_{8}' \subset \bf{P}^7$, of degree 16, having Betti table of type [441], on component [441b]. For an artinian reduction $A_F$, the quadratic part of the ideal $F^\perp$ is the ideal of two skew lines, and $F^\perp$ contains pencils of ideals of three points on one line and three fix points on the other. So we construct $X_{8}$ in the intersection of two cubics in a P5 and $X_{8}'$ in the intersection of two cubics in another P5. In the construction the intersection $X\cup X'$ of a component $X$ with the other is an anticanonical divisor on $X$.

The Betti table is $\phantom{WWWW} \begin{matrix} &0&1&2&3&4\\ \text{total:}&1&9&16&9&1\\ \text{0:}&1&\text{.}&\text{.}&\text{.}&\text{.}\\ \text{1:}&\text{.}&4&4&1&\text{.}\\ \text{2:}&\text{.}&4&8&4&\text{.}\\ \text{3:}&\text{.}&1&4&4&\text{.}\\ \text{4:}&\text{.}&\text{.}&\text{.}&\text{.}&1\\ \end{matrix} $

i1 : kk=QQ;

i2 : U=kk[y0,y1,y2,y3,y4,y5,y6,y7];

i3 : P5a=ideal(y0,y1);--a P5 containing P3c

o3 : Ideal of U

i4 : P5b=ideal(y2,y3);--another P5 containing P3c

o4 : Ideal of U

i5 : P3=P5a+P5b;--the common P3 of P5a and P5b

o5 : Ideal of U

i6 : F0=matrix{{random(2,U),random(2,U)},{random(2,U),random(2,U)}};--a 2x2 matrix of quadrics,

             2      2
o6 : Matrix U  <-- U

i7 : F1=matrix{{y2},{y3}}|F0;--a 2x3 matrix, one columns of linear forms, and two of quadrics,

             2      3
o7 : Matrix U  <-- U

i8 : X8a=P5a+minors(2,F1);--a 3-fold of degree 8 in P5a linked (1,1,3,3) to P3

o8 : Ideal of U

i9 : F2=matrix{{y0},{y1}}|F0;--a 2x3 matrix, one columns of linear forms, and two of quadrics,

             2      3
o9 : Matrix U  <-- U

i10 : X8b=P5b+minors(2,F2);--a 3-fold of degree 8 in P5b linked  (1,1,3,3) to P3

o10 : Ideal of U

i11 : X16=intersect(X8a,X8b);-- a 3-fold of degree 16 in P7 with betti table of type 441b

o11 : Ideal of U

i12 : betti res X16

             0 1  2 3 4
o12 = total: 1 9 16 9 1
          0: 1 .  . . .
          1: . 4  4 1 .
          2: . 4  8 4 .
          3: . 1  4 4 .
          4: . .  . . 1

o12 : BettiTally

Type [441b], CY of degree 16 -- lifting to a 3-fold with components of degrees 8, 8

See also